***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Sep 13, 2024                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJQ5590-AU     drain  gate  source
Lg     gate   g1   2.2n
Ld     drain  d1   100p
Ls     source s1   350p
Rs      s1    s2   205u TC=3m
Rg     g1    g2     1.136
M1      d2    g2    s2    s2    DMOS    L=1u   W=1u
.MODEL DMOS NMOS ( KP=142.7  VTO=3.83  LEVEL=3  VMAX=1.2e5  ETA=0.006  gamma=1.7 nfs=1.000e+11)
Rd     d1    d2    11.6m TC=6.8m,16u
Dbd     s2    d2    Dbt
.MODEL     Dbt    D(BV=165     TBV1=6.670e-4  TBV2=-2.300e-8 CJO=1.626e-9  M=1.805  VJ=6.464e+1)
Dbody   s2   21    DBODY
.MODEL DBODY  D(IS=2.377e-15  N=7.936e-1  RS=0.04u  EG=1.160  TT=30n  ikf=1.361)
Rdiode  d1  21    1.279e-3 TC=2.2m
.MODEL   sw    NMOS(VTO=0  KP=10   LEVEL=1)
Maux      g2   c    a    a   sw
Maux2     b    d    g2    g2   sw
Eaux      c    a    d2    g2   1
Eaux2     d    g2   d2    g2   -1
Cox       b    d2   9.528e-10
.MODEL     DGD    D(M=1.043   CJO=9.528e-10   VJ=3.644)
Rpar      b    d2   1Meg
Dgd       a    d2   DGD
Rpar2     d2   a    10Meg
Cgs     g2    s2    2.287e-9
.ENDS
*$
